//+------------------------------------------------------------------+
//|                                    i-SpectrAnalysis_MA_Cloud.mq5 |
//|                                           Copyright © 2006, klot |
//|                                                     klot@mail.ru |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2006, klot"
#property link      "klot@mail.ru"
//---- номер версии индикатора
#property version   "1.00"
//---- отрисовка индикатора в основном окне
#property indicator_chart_window
//---- количество индикаторных буферов 2
#property indicator_buffers 2 
//---- использовано всего одно графическое построение
#property indicator_plots   1
//+----------------------------------------------+
//| Параметры отрисовки индикатора               |
//+----------------------------------------------+
//---- отрисовка индикатора в виде цветного облака
#property indicator_type1   DRAW_FILLING
//---- в качестве цветов индикатора использованы
#property indicator_color1  clrPaleGreen,clrHotPink
//---- отображение метки индикатора
#property indicator_label1  "i-SpectrAnalysis_MA_Cloud"
//+----------------------------------------------+
//| Объявление констант                          |
//+----------------------------------------------+
#define RESET 0                // константа для возврата терминалу команды на пересчет индикатора
//+----------------------------------------------+
//| Описание библиотеки dt_FFT.mqh               |
//+----------------------------------------------+
#include <dt_FFT.mqh> 
//+----------------------------------------------+
//| Входные параметры индикатора                 |
//+----------------------------------------------+
input uint   MAPeriod=13;
input  ENUM_MA_METHOD   MAType=MODE_EMA;
input ENUM_APPLIED_PRICE   MAPrice=PRICE_CLOSE;
input uint N = 7;   // Длина ряда
input uint SS = 20; // Коэффициент сглаживания
input int Shift=0;  // Сдвиг индикатора по горизонтали в барах
//+----------------------------------------------+
//---- объявление динамических массивов, которые будут в 
//---- дальнейшем использованы в качестве индикаторных буферов
double ExtSpanABuffer[],ExtSpanBBuffer[];
int M,tnn1,ss;
//----
double aa[],bb[];
//---- объявление целочисленных переменных начала отсчета данных
int min_rates_total;
//---- объявление целочисленных переменных для хендлов индикаторов
int Ind_Handle;
//+------------------------------------------------------------------+   
//| i-SpectrAnalysis_MA indicator initialization function            |
//+------------------------------------------------------------------+ 
int OnInit()
  {
//---- инициализация переменных начала отсчета данных
   tnn1=int(MathPow(2,N));
   M=ArrayResize(aa,tnn1+1);
   ArraySetAsSeries(aa,true);
   ArrayResize(bb,tnn1+1);
   ArraySetAsSeries(bb,true);
   ss=int(MathMin(SS,M));
   min_rates_total=int(M+MAPeriod);
//--- получение хендла индикатора iMA
   Ind_Handle=iMA(Symbol(),PERIOD_CURRENT,MAPeriod,0,MAType,MAPrice);
   if(Ind_Handle==INVALID_HANDLE)
     {
      Print(" Не удалось получить хендл индикатора iMA");
      return(INIT_FAILED);
     }
//---- превращение динамического массива в индикаторный буфер
   SetIndexBuffer(0,ExtSpanABuffer,INDICATOR_DATA);
//---- индексация элементов в буфере как в таймсерии
   ArraySetAsSeries(ExtSpanABuffer,true);
//---- превращение динамического массива в индикаторный буфер
   SetIndexBuffer(1,ExtSpanBBuffer,INDICATOR_DATA);
//---- индексация элементов в буфере как в таймсерии
   ArraySetAsSeries(ExtSpanBBuffer,true);
//---- осуществление сдвига начала отсчета отрисовки индикатора
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
//---- установка значений индикатора, которые не будут видимы на графике
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,EMPTY_VALUE);
//---- осуществление сдвига индикатора по горизонтали на InpKijun
   PlotIndexSetInteger(0,PLOT_SHIFT,Shift);
//--- создание имени для отображения в отдельном подокне и во всплывающей подсказке
   IndicatorSetString(INDICATOR_SHORTNAME,"i-SpectrAnalysis_MA_Cloud");
//--- определение точности отображения значений индикатора
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
//--- завершение инициализации
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+ 
//| i-SpectrAnalysis_MA iteration function                           |
//+------------------------------------------------------------------+ 
int OnCalculate(const int rates_total,    // количество истории в барах на текущем тике
                const int prev_calculated,// количество истории в барах на предыдущем тике
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- проверка количества баров на достаточность для расчета
   if(rates_total<min_rates_total || BarsCalculated(Ind_Handle)<rates_total) return(RESET);
//----
   for(int bar=rates_total-1; bar>=prev_calculated && !IsStopped(); bar--) ExtSpanABuffer[bar]=0.0;
   for(int bar=rates_total-1; bar>=prev_calculated && !IsStopped(); bar--) ExtSpanBBuffer[bar]=0.0;
//--- копируем вновь появившиеся данные в массив
   if(CopyBuffer(Ind_Handle,0,0,M,aa)<=0) return(RESET);
//----
   int end=M-1;
   fastcosinetransform(aa,tnn1,false);
   for(int kkk=0; kkk<=end && !IsStopped(); kkk++) if(kkk>=ss) aa[kkk]=0.0;
   fastcosinetransform(aa,tnn1,true);
   for(int rrr=0; rrr<=end && !IsStopped(); rrr++) ExtSpanBBuffer[rrr]=aa[rrr];
//----
   for(int iii=M-1; iii>=0 && !IsStopped(); iii--) bb[iii]=close[rates_total-1-iii];
   fastcosinetransform(bb,tnn1,false);
   for(int kkk=0; kkk<=end && !IsStopped(); kkk++) if(kkk>=ss) bb[kkk]=0.0;
   fastcosinetransform(bb,tnn1,true);
   for(int rrr=0; rrr<=end && !IsStopped(); rrr++) ExtSpanABuffer[rrr]=bb[rrr];
//----     
   return(rates_total);
  }
//+------------------------------------------------------------------+